weak 底层原理

1 weak 原理

实质是 Runtime 维护的一个 weak 表.该表是一个 hash 表,其中的 key 是 weak 对象的地址,value 是指向该对象的所有 weak 指针的地址数组.

weak 的实现步骤

1. 初始化:Runtime 会调用 objc_initWeak() 函数,初始化一个新的指向对象的 weak 指针地址.
2. 添加引用: objc_initWeak() 会调用 objc_storeWeak(). objc_storeWeak() 的用途是更新指针指向,创建弱引用表.
3. 释放时: 调用 clearDeallocating().该函数首先根据 key (对象地址)找到对应的 value (存放 weak 指针的数组).然后遍历数组,把其中的对象设置为 nil,最后把该 entry 从 weak 表中删除并清理对象的记录.

2 weak 的创建

1 创建流程简图

创建流程简图

2 objc_initWeak

objc_initWeak(id *location, id newObj)
{
    if (!newObj) {
        *location = nil;
        return nil;
    }

    return storeWeak<DontHaveOld, DoHaveNew, DoCrashIfDeallocating>
        (location, (objc_object*)newObj);
}

解析：
location：表示 __weak 指针的地址。用来将 __weak 指针指向的内容置为 nil。
newObj：引用的对象。


storeWeak：
// Update a weak variable.
// If HaveOld is true, the variable has an existing value 
//   that needs to be cleaned up. This value might be nil.
// If HaveNew is true, there is a new value that needs to be 
//   assigned into the variable. This value might be nil.
// If CrashIfDeallocating is true, the process is halted if newObj is 
//   deallocating or newObj's class does not support weak references. 
//   If CrashIfDeallocating is false, nil is stored instead.
enum CrashIfDeallocating {
    DontCrashIfDeallocating = false, DoCrashIfDeallocating = true
};
template <HaveOld haveOld, HaveNew haveNew,
          CrashIfDeallocating crashIfDeallocating>
static id 
storeWeak(id *location, objc_object *newObj)
{
    assert(haveOld  ||  haveNew);
    if (!haveNew) assert(newObj == nil);

    Class previouslyInitializedClass = nil;
    id oldObj;
    SideTable *oldTable;
    SideTable *newTable;

    // Acquire locks for old and new values.
    // Order by lock address to prevent lock ordering problems. 
    // Retry if the old value changes underneath us.
 retry:
    ✅// 如果weak指针之前弱引用过一个obj，则将这个obj所对应的SideTable取出，赋值给oldTable
    if (haveOld) {
        oldObj = *location;
        oldTable = &SideTables()[oldObj];
    } else {
        // 没有弱引用过，则oldTable = nil
        oldTable = nil;
    }
    ✅// 如果weak指针要弱引用一个新的obj，则将该obj对应的SideTable取出，赋值给newTable
    if (haveNew) {
        newTable = &SideTables()[newObj];
    } else {
        newTable = nil;
    }
    ✅// 加锁操作，防止多线程中竞争冲突
    SideTable::lockTwo<haveOld, haveNew>(oldTable, newTable);
    ✅// location 应该与 oldObj 保持一致，如果不同，说明当前的 location 已经处理过 oldObj 可是又被其他线程所修改
    if (haveOld  &&  *location != oldObj) {
        SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
        goto retry;
    }

    // Prevent a deadlock between the weak reference machinery
    // and the +initialize machinery by ensuring that no 
    // weakly-referenced object has an un-+initialized isa.
    if (haveNew  &&  newObj) {
        Class cls = newObj->getIsa();
        ✅// 如果cls还没有初始化，先初始化，再尝试设置弱引用
        if (cls != previouslyInitializedClass  &&  
            !((objc_class *)cls)->isInitialized()) 
        {
            SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
            _class_initialize(_class_getNonMetaClass(cls, (id)newObj));

            // If this class is finished with +initialize then we're good.
            // If this class is still running +initialize on this thread 
            // (i.e. +initialize called storeWeak on an instance of itself)
            // then we may proceed but it will appear initializing and 
            // not yet initialized to the check above.
            // Instead set previouslyInitializedClass to recognize it on retry.
            ✅// 完成初始化后进行标记
            previouslyInitializedClass = cls;
            ✅// newObj 初始化后，重新获取一遍newObj
            goto retry;
        }
    }

    // Clean up old value, if any.
   ✅// 如果weak指针之前弱引用过别的对象oldObj，则调用weak_unregister_no_lock，在oldObj的weak_entry_t中移除该weak指针地址
    if (haveOld) {
        weak_unregister_no_lock(&oldTable->weak_table, oldObj, location);
    }

    // Assign new value, if any.
    ✅// 如果weak指针需要弱引用新的对象newObj
    if (haveNew) {
       ✅ // 调用weak_register_no_lock方法，将weak指针的地址记录到newObj对应的weak_entry_t中
        newObj = (objc_object *)
            weak_register_no_lock(&newTable->weak_table, (id)newObj, location, 
                                  crashIfDeallocating);
        // weak_register_no_lock returns nil if weak store should be rejected

        // Set is-weakly-referenced bit in refcount table.
        ✅// 更新newObj的isa指针的weakly_referenced bit标志位
        if (newObj  &&  !newObj->isTaggedPointer()) {
            newObj->setWeaklyReferenced_nolock();
        }

        // Do not set *location anywhere else. That would introduce a race.
        ✅// *location 赋值，也就是将weak指针直接指向了newObj，而且没有将newObj的引用计数+1
        *location = (id)newObj;
    }
    else {
        // No new value. The storage is not changed.
    }
    
    SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);

    return (id)newObj;
}

解析：
HaveOld：weak 指针之前是否已经指向了一个弱引用。
HaveNew：weak 指针是否需要指向一个新引用。
CrashIfDeallocating：如果被弱引用的对象正在析构，此时再弱引用该对象，是否应该 crash。


weak_unregister_no_lock：
void weak_unregister_no_lock(weak_table_t *weak_table, id referent_id, 
                        id *referrer_id)
{
    ✅// 拿到以前弱引用的对象和对象的地址
    objc_object *referent = (objc_object *)referent_id;
    objc_object **referrer = (objc_object **)referrer_id;

    weak_entry_t *entry;

    if (!referent) return;
    ✅// 查找到以前弱引用的对象 referent 所对应的 weak_entry_t
    if ((entry = weak_entry_for_referent(weak_table, referent))) {
        ✅// 在以前弱引用的对象 referent 所对应的 weak_entry_t 的 hash 数组中，移除弱引用 referrer
        remove_referrer(entry, referrer);
        ✅// 移除元素之后， 要检查一下 weak_entry_t 的 hash 数组是否已经空了
        bool empty = true;
        if (entry->out_of_line()  &&  entry->num_refs != 0) {
            empty = false;
        }
        else {
            for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
                if (entry->inline_referrers[i]) {
                    empty = false; 
                    break;
                }
            }
        }
        ✅// 如果 weak_entry_t 的hash数组已经空了，则需要将 weak_entry_t 从 weak_table 中移除
        if (empty) {
            weak_entry_remove(weak_table, entry);
        }
    }

    // Do not set *referrer = nil. objc_storeWeak() requires that the 
    // value not change.
}

分析：
1. 如果 weak 指针在指向 obj 之前，已经弱引用了其他的对象，则需要先将 weak 指针从其他对象的 weak_entry_t 的 hash 数组中移除。在 storeWeak 方法中会调用 weak_unregister_no_lock 函数来做移除操作。
2. weak_unregister_no_lock 函数首先会在 weak_table 中找出以前被弱引用的对象 referent 对应的 weak_entry_t，在 weak_entry_t 中移除被弱引用的对象 referrer。
3. 移除元素后，判断此时 weak_entry_t 中是否还有元素。如果此时 weak_entry_t 已经没有元素了，则需要将 weak_entry_t 从 weak_table 中移除。


weak_register_no_lock：
id weak_register_no_lock(weak_table_t *weak_table, id referent_id, 
                      id *referrer_id, bool crashIfDeallocating)
{
    ✅//首先获取需要弱引用对象
    objc_object *referent = (objc_object *)referent_id;
    objc_object **referrer = (objc_object **)referrer_id;
    ✅// 如果被弱引用对象referent为nil 或者被弱引用对象采用了TaggedPointer计数方式，则直接返回
    if (!referent  ||  referent->isTaggedPointer()) return referent_id;

    // ensure that the referenced object is viable
    ✅// 确保被引用的对象可用（没有在析构，同时应该支持weak弱引用）
    bool deallocating;
    if (!referent->ISA()->hasCustomRR()) {
        deallocating = referent->rootIsDeallocating();
    }
    else {
        BOOL (*allowsWeakReference)(objc_object *, SEL) = 
            (BOOL(*)(objc_object *, SEL))
            object_getMethodImplementation((id)referent, 
                                           SEL_allowsWeakReference);
        if ((IMP)allowsWeakReference == _objc_msgForward) {
            return nil;
        }
        deallocating =
            ! (*allowsWeakReference)(referent, SEL_allowsWeakReference);
    }
    ✅// 如果是正在析构的对象，那么不能够被弱引用
    if (deallocating) {
        if (crashIfDeallocating) {
            _objc_fatal("Cannot form weak reference to instance (%p) of "
                        "class %s. It is possible that this object was "
                        "over-released, or is in the process of deallocation.",
                        (void*)referent, object_getClassName((id)referent));
        } else {
            return nil;
        }
    }

    // now remember it and where it is being stored
    ✅// 在 weak_table 中找到被弱引用对象 referent 对应的 weak_entry,并将 referrer 加入到 weak_entry 中
    weak_entry_t *entry;
    if ((entry = weak_entry_for_referent(weak_table, referent))) {
        ✅// 如果能找到 weak_entry,则讲 referrer 插入到 weak_entry 中
        append_referrer(entry, referrer);
    } 
    else {
        ✅// 如果找不到 weak_entry，就新建一个
        weak_entry_t new_entry(referent, referrer);
        weak_grow_maybe(weak_table);
        weak_entry_insert(weak_table, &new_entry);
    }

    // Do not set *referrer. objc_storeWeak() requires that the 
    // value not change.

    return referent_id;
}

分析：
1. isTaggedPointer 和 deallocating 前置条件判断，这些都是不能进行弱引用的情况。
2. 如果可以被弱引用，则将被弱引用对象所在的 weak_table 中的 weak_entry_t 哈希数组中取出对应的 weak_entry_t。（如果 weak_entry_t 不存在，则会新建一个。）然后将指向被弱引用对象地址的指针 referrer 通过函数 append_referrer 插入到对应的 weak_entry_t 引用数组。


append_referrer：
static void append_referrer(weak_entry_t *entry, objc_object **new_referrer)
{
    ✅// 如果weak_entry 使用静态数组 inline_referrers
    if (! entry->out_of_line()) {
        // Try to insert inline.
        ✅// 尝试将 referrer 插入数组
        for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
            if (entry->inline_referrers[i] == nil) {
                entry->inline_referrers[i] = new_referrer;
                return;
            }
        }

        // Couldn't insert inline. Allocate out of line.
        ✅// 如果inline_referrers的位置已经存满了，则要转型为 referrers，动态数组
        weak_referrer_t *new_referrers = (weak_referrer_t *)
            calloc(WEAK_INLINE_COUNT, sizeof(weak_referrer_t));
        // This constructed table is invalid, but grow_refs_and_insert
        // will fix it and rehash it.
        for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
            new_referrers[i] = entry->inline_referrers[I];
        }
        entry->referrers = new_referrers;
        entry->num_refs = WEAK_INLINE_COUNT;
        entry->out_of_line_ness = REFERRERS_OUT_OF_LINE;
        entry->mask = WEAK_INLINE_COUNT-1;
        entry->max_hash_displacement = 0;
    }

    assert(entry->out_of_line());
    ✅// 如果动态数组中元素个数大于或等于数组总空间的3/4，则扩展数组空间为当前长度的一倍，然后将 referrer 插入数组
    if (entry->num_refs >= TABLE_SIZE(entry) * 3/4) {
        return grow_refs_and_insert(entry, new_referrer);
    }
    ✅// 如果不需要扩容，直接插入到weak_entry中
    ✅// & (entry->mask) 保证 begin 的位置只能大于或等于数组的长度
    size_t begin = w_hash_pointer(new_referrer) & (entry->mask);
    size_t index = begin;
    size_t hash_displacement = 0;
    while (entry->referrers[index] != nil) {
        hash_displacement++;
        index = (index+1) & entry->mask;
        if (index == begin) bad_weak_table(entry);
    }
    if (hash_displacement > entry->max_hash_displacement) {
        entry->max_hash_displacement = hash_displacement;
    }
    weak_referrer_t &ref = entry->referrers[index];
    ref = new_referrer;
    entry->num_refs++;
}

3 创建小结

Runtime 维护了一个弱引用表，该表是一个 hash 表，以弱引用对象的指针地址为 key， weak 的地址数组为 value 保存在 weak_entry_t 中。

1. 先从全局散列表 (SideTables) 中找到对应的弱引用表 weak_table。在 weak_table 中找到被弱引用对象的 referent，创建或者插入对应的 weak_entry_t。
2. 然后通过 append_referrer(entry, referrer) 将新弱引⽤的对象加到 entry 中。
3. 最后通过 weak_entry_insert 把 entry 加⼊到我们的 weak_table。

3 weak 销毁

1 销毁简图

销毁流程简图

2 _objc_rootDealloc

- (void)dealloc {
    _objc_rootDealloc(self);
}
**********************************
void _objc_rootDealloc(id obj)
{
    assert(obj);

    obj->rootDealloc();
}
***********************************
inline void objc_object::rootDealloc()
{
    //✅如果是Tagged Pointer，就直接返回
    if (isTaggedPointer()) return;  // fixme necessary?

    /*
    ✅如果同时满足 
    1. 是优化过的isa、
    2. 没有被weak指针引用过、
    3. 没有关联对象、
    4. 没有C++析构函数、
    5. 没有sideTable，
    就可以直接释放内存free()
    */
    if (fastpath(isa.nonpointer  &&  
                 !isa.weakly_referenced  &&  
                 !isa.has_assoc  &&  
                 !isa.has_cxx_dtor  &&  
                 !isa.has_sidetable_rc))
    {
        assert(!sidetable_present());
        free(this);
    } 
    else {//否则的话就需要通过下面的函数处理
        object_dispose((id)this);
    }
}


object_dispose：
id 
object_dispose(id obj)
{
    if (!obj) return nil;

    objc_destructInstance(obj);    
    free(obj);

    return nil;
}


objc_destructInstance：
void *objc_destructInstance(id obj) 
{
    if (obj) {
        // Read all of the flags at once for performance
        bool cxx = obj->hasCxxDtor();
        bool assoc = obj->hasAssociatedObjects();

        // This order is important.
       ✅ // 如果有C++析构函数，则从运行相关函数
        if (cxx) object_cxxDestruct(obj); 
        ✅// 如果有关联对象，则移除所有的关联对象，并将其自身从Association Manager的map中移除
        if (assoc) _object_remove_assocations(obj); 
        ✅// 继续清理其它相关的引用
        obj->clearDeallocating(); 
    }
    return obj;
}


clearDeallocating：
inline void 
objc_object::clearDeallocating()
{
    if (slowpath(!isa.nonpointer)) {
        // Slow path for raw pointer isa.
        ✅// 如果要释放的对象没有采用了优化过的isa引用计数
        sidetable_clearDeallocating();
    }
    else if (slowpath(isa.weakly_referenced  ||  isa.has_sidetable_rc)) {
        // Slow path for non-pointer isa with weak refs and/or side table data.
        ✅// 如果要释放的对象采用了优化过的isa引用计数，并且有弱引用或者使用了sideTable的辅助引用计数
        clearDeallocating_slow();
    }

    assert(!sidetable_present());
}


clearDeallocating_slow：
NEVER_INLINE void
objc_object::clearDeallocating_slow()
{
    assert(isa.nonpointer  &&  (isa.weakly_referenced || isa.has_sidetable_rc));
    ✅// 在全局的SideTables中，以this指针(要释放的对象)为key，找到对应的SideTable
    SideTable& table = SideTables()[this];
    table.lock();
    if (isa.weakly_referenced) {
        ✅//要释放的对象被弱引用了，通过weak_clear_no_lock函数将指向该对象的弱引用指针置为nil
        weak_clear_no_lock(&table.weak_table, (id)this);
    }
    ✅//使用了sideTable的辅助引用计数,直接在SideTable中擦除该对象的引用计数
    if (isa.has_sidetable_rc) {
        table.refcnts.erase(this);
    }
    table.unlock();
}


weak_clear_no_lock：
void 
weak_clear_no_lock(weak_table_t *weak_table, id referent_id) 
{
    ✅//获取被弱引用对象的地址
    objc_object *referent = (objc_object *)referent_id;
    ✅// 根据对象地址找到被弱引用对象referent在weak_table中对应的weak_entry_t
    weak_entry_t *entry = weak_entry_for_referent(weak_table, referent); 
    if (entry == nil) {
        /// XXX shouldn't happen, but does with mismatched CF/objc
        //printf("XXX no entry for clear deallocating %p\n", referent);
        return;
    }

    // zero out references
    weak_referrer_t *referrers;
    size_t count;
    
    ✅// 找出弱引用该对象的所有weak指针地址数组
    if (entry->out_of_line()) {
        referrers = entry->referrers;
        count = TABLE_SIZE(entry);
    } 
    else {
        referrers = entry->inline_referrers;
        count = WEAK_INLINE_COUNT;
    }
    ✅// 遍历取出每个weak指针的地址
    for (size_t i = 0; i < count; ++i) {
        objc_object **referrer = referrers[I]; 
        if (referrer) {
            ✅// 如果weak指针确实弱引用了对象 referent，则将weak指针设置为nil
            if (*referrer == referent) { 
                *referrer = nil;
            }
            ✅// 如果所存储的weak指针没有弱引用对象 referent，这可能是由于runtime代码的逻辑错误引起的，报错
            else if (*referrer) { 
                _objc_inform("__weak variable at %p holds %p instead of %p. "
                             "This is probably incorrect use of "
                             "objc_storeWeak() and objc_loadWeak(). "
                             "Break on objc_weak_error to debug.\n", 
                             referrer, (void*)*referrer, (void*)referent);
                objc_weak_error();
            }
        }
    }
    weak_entry_remove(weak_table, entry);
}

3 销毁流程小结：

1. 首先根据对象地址获取所有 weak 指针地址的数组。
2. 然后遍历这个数组把对应的数据清空置为 nil。
3. 将 weak_entry_t 移除出弱引用表 weak_table。

4 总结

1. 当一个对象 obj 被 weak 指针指向时，这个 weak 指针会被存储到 sideTable 的 weak_table 散列表中以 obj 作为 key 对应的 weak 指针数组里面。
2. 当一个对象 obj 的 dealloc 方法被调用时，Runtime 会以 obj 为 key，从 sideTable 的 weak_table 散列表中，找出对应的 weak 指针数组，然后将里面的 weak 指针逐个置为 nil。