【以太坊开发】手把手教你发个数字货币及怎样分配激励

作者: 海阳之新 | 来源:发表于2018-05-12 17:20 被阅读384次

【以太坊开发】手把手教你发布众筹智能合约进行ICO
【以太坊开发】手把手教你发个数字货币及怎样分配激励
以太坊Solidity开发入门(基础篇)
新的机遇！俄罗斯国家开发银行发行自己的数字货币VEB了！
solidity 0.5.7简明教程
如何购买以太坊
如何购买以太坊
切记盲目参与项目，加密数字货币的四大特点
V神：震惊世界的天才少年！
币圈知识:交易所基础交易名词及术语解释

笔者这些天从以太坊官网etherscan.io扒了一些token的源代码，如ABT、DRGN、BNB、EOS等，发现编写一个能够发布到以太坊公网的智能合约其实并不难，甚至可以将其模板化，因为它们大部分都遵循了ERC20标准，且设计模式都比较统一，如图所示：

智能合约的设计模式和某些代码的写法，后来又在github中这个开源项目Openzeppelin-solidity找到了出处。Openzeppelin-solidity是一套能够给我们方便提供编写加密合约的函数库，同时里面也提供了兼容ERC20的智能合约。

说个题外话，智能合约编写不好也会有安全漏洞，比如美链BEC被攻击事件，如果有兴趣，可点击我的另一篇文章了解详情：【以太坊开发】BeautyChain (BEC) 溢出漏洞分析

综上所述，笔者编写了一个合约模板，如果你对以太坊的Solidity语言不太熟悉，完全可以将以下合约代码拿来就用，只需要在部署时，传入自己想要构建合约的发行总量、代币名称、代币icon即可。

一、拷贝智能合约模板

pragma solidity ^0.4.18;

library SafeMath {

    /* 加法 */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        assert(c >= a);
        return c;
    }

    /* 减法 */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        assert(b <= a);
        return a - b;
    }

    /* 乘法 */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }
        uint256 c = a * b;
        assert(c / a == b);
        return c;
    }

    /* 除法 */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a / b;
        return c;
    }

}

/**
 * @dev 合约管理员
 * 登记合约管理员地址，并可实现管理员转让
 */
contract Ownable {
    /* 管理员钱包地址 */
    address public owner;

    /* 转让管理员日志 */
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev 设置合约创建者为合约管理员
     */
    function Ownable() public {
        owner = msg.sender;
    }

    /**
    * @dev 仅限合约管理员操作
    */
    modifier onlyOwner() {
        require(msg.sender == owner);
        _;
    }


    /**
    * @dev 将合约管理员权限转让给新管理员
    * @param newOwner 新管理员钱包地址
    */
    function transferOwnership(address newOwner) public onlyOwner {
        require(newOwner != address(0));
        OwnershipTransferred(owner, newOwner);
        owner = newOwner;
    }

}

/* 合约交易开关，只有合约管理员才能操作 */
contract Pausable is Ownable {
    /* 开关事件，如果没有参数，仅记录事件名 */
    event Pause();
    event Unpause();

    /* 合约交易开关变量 */
    bool public paused = false;

    /**
    * @dev 仅限未停止合约交易情况下操作
    */
    modifier whenNotPaused() {
        require(!paused);
        _;
    }

    /**
    * @dev 仅限停止合约交易情况下操作
    */
    modifier whenPaused() {
        require(paused);
        _;
    }

    /**
    * @dev 合约管理员停止合约交易
    */
    function pause() onlyOwner whenNotPaused public {
        paused = true;
        Pause();
    }

    /**
    * @dev 合约管理员开启合约交易
    */
    function unpause() onlyOwner whenPaused public {
        paused = false;
        Unpause();
    }
}

/* ERC20标准 */
contract ERC20Basic {
    /* token总发行量 */
    uint256 public totalSupply;
    /* 获取指定钱包地址的token余额 */
    function balanceOf(address who) public view returns (uint256);
    /* 转账value个token到指定钱包地址to */
    function transfer(address to, uint256 value) public returns (bool);
    /* 转账日志 */
    event Transfer(address indexed from, address indexed to, uint256 value);
}

/* ERC20标准 */
contract ERC20 is ERC20Basic {
    /* 获取允许spender还能提取token的额度 */
    function allowance(address owner, address spender) public view returns (uint256);
    /* 批准spender账户从自己的账户转移value个token，可分多次转移 */
    function transferFrom(address from, address to, uint256 value) public returns (bool);
    /* 与approve搭配使用，approve批准之后，调用transferFrom来转移token */
    function approve(address spender, uint256 value) public returns (bool);
    /* 当调用approve成功时，一定要触发Approval事件 */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

/* 基础合约，实现ERC20标准 */
contract BasicToken is ERC20Basic {
    /* 导入安全运算库 */
    using SafeMath for uint256;

    /* 存储指定钱包的token余额 */
    mapping(address => uint256) balances;

    /**
     * @dev 转移_value个token到指定钱包地址_to
     * @param _to 指定钱包地址
     * @param _value token个数
     */
    function transfer(address _to, uint256 _value) public returns (bool) {
        require(_to != address(0));
        require(_value <= balances[msg.sender]);

        /* 如果余额不足，SafeMath.sub将抛出异常 */
        balances[msg.sender] = balances[msg.sender].sub(_value);
        balances[_to] = balances[_to].add(_value);
        Transfer(msg.sender, _to, _value);
        return true;
    }

    /**
     * @dev 获取指定钱包地址的token余额
     * @param _owner 指定钱包地址
     * @return uint256
     */
    function balanceOf(address _owner) public view returns (uint256 balance) {
        return balances[_owner];
    }

}

/* 标准合约，实现ERC20标准 */
contract StandardToken is ERC20, BasicToken {

    /* 指定账号的token额度 */
    mapping (address => mapping (address => uint256)) internal allowed;


    /**
     * @dev 从一个钱包地址转移token到另一个钱包地址，更新被允许的token额度
     * 与approve搭配使用，approve批准之后，调用transferFrom来转移token
     * @param _from 从哪个钱包地址发送token
     * @param _to 转移到哪个钱包地址
     * @param _value 转移多少个token，个数必须为非负数
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
        require(_to != address(0));
        require(_value <= balances[_from]);
        require(_value <= allowed[_from][msg.sender]);

        balances[_from] = balances[_from].sub(_value);
        balances[_to] = balances[_to].add(_value);
        allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
        Transfer(_from, _to, _value);
        return true;
    }


    /**
     * @dev 批准spender从自己的账户转移value个token，可分多次转移
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     * @param _spender 将要花费token的地址
     * @param _value token个数，可以理解成token额度
    */
    function approve(address _spender, uint256 _value) public returns (bool) {
        allowed[msg.sender][_spender] = _value;
        Approval(msg.sender, _spender, _value);
        return true;
    }

    /**
     * @dev 获取允许spender提取token的额度
     * @param _owner 上一级钱包地址，如合约管理员钱包地址
     * @param _spender 将要花费token的地址
     * @return uint256
     */
    function allowance(address _owner, address _spender) public view returns (uint256) {
        return allowed[_owner][_spender];
    }

    /**
     * @dev 增加spender的可用token额度
     * @param _spender 将要花费token的地址
     * @param _addedValue 需要增加token的个数，可理解成可使用的token额度
     */
    function increaseApproval(address _spender, uint _addedValue) public returns (bool) {
        allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
        Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
        return true;
    }

    /**
     * @dev 减少spender的可用token额度
     * @param _spender 将要花费token的地址
     * @param _subtractedValue 需要减少token的个数，可理解成可使用的token额度
     */
    function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool) {
        uint oldValue = allowed[msg.sender][_spender];
        if (_subtractedValue > oldValue) {
            allowed[msg.sender][_spender] = 0;
        } else {
            allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
        }
        Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
        return true;
    }

}

contract PausableToken is StandardToken, Pausable {

    function transfer(address _to, uint256 _value) public whenNotPaused returns (bool) {
        return super.transfer(_to, _value);
    }

    function transferFrom(address _from, address _to, uint256 _value) public whenNotPaused returns (bool) {
        return super.transferFrom(_from, _to, _value);
    }

    function approve(address _spender, uint256 _value) public whenNotPaused returns (bool) {
        return super.approve(_spender, _value);
    }

    function increaseApproval(address _spender, uint _addedValue) public whenNotPaused returns (bool success) {
        return super.increaseApproval(_spender, _addedValue);
    }

    function decreaseApproval(address _spender, uint _subtractedValue) public whenNotPaused returns (bool success) {
        return super.decreaseApproval(_spender, _subtractedValue);
    }
}

contract MyTestToken is PausableToken {
    /* 我的token的名称 */
    string public name;
    /* 我的token的icon */
    string public symbol;
    /* 我的token的精确位数 */
    uint256 public decimals = 18;

    function MyTestToken(uint256 initialSupply, string tokenName, string tokenSymbol) public {
        /* 我的token发行总量 */
        totalSupply = initialSupply * 10 ** uint256(decimals);
        /* 我的token余额 */
        balances[msg.sender] = totalSupply;
        /* 初始化我的token的名称 */
        name = tokenName;
        /* 我的token的icon */
        symbol = tokenSymbol;
    }
}

如上代码所示，我们仅需要在创建MyTestToken合约时，传入自己想要构建合约的发行总量、代币名称、代币icon即可。

二、创建合约并发布到测试网络

1、准备发布工具
发布前我们需要做一些准备工作：

安装Remix IDE，请参见我的另一篇文章：【以太坊开发】Remix IDE本地部署与配置个性风格
安装MetaMask，请参见我的另一篇文章：【以太坊开发】以太坊钱包MetaMask使用教程

以上是两款我们发布合约的工具。以下涉及到的一些细节操作均在上面文章中有介绍，不再冗述。

2、创建合约的管理员
我们需要在MetaMask开通一个钱包地址，这个钱包地址将做为我们发布合约的管理员，在以后合约管理中一些高级操作都只有合约管理员才有权限操作，如下：
0x2D80ed00A372AF341887F473eD6241f1973C5D59
将这个钱包地址命名成我的英文名Simon（后续文章也以此命名，方便引用），并保证这个账号有一定数量的测试ETH（作为部署合约的燃料），因为发布合约就等于生成一笔交易，需要消耗gas（可理解成燃料），而消耗gas是通过扣除ETH来实现的。如下图：

3、粘贴代码到Remix
打开以太坊官方提供的在线IDE：https://remix.ethereum.org/，由于访问速度较慢，笔者将其下载到了本地并部署。在Remix中的工作区中，粘贴合约代码，如图（下载看大图）：

4、编译合约
如上图第2步，勾选Auto compile，刷新页面，可自动完成合约编译。

5、部署合约
我们将合约发布到测试网络Ropsten（基于POW共识算法，与以太坊主网一致）
在Remix的右侧调试区，我们切换到Run标签栏，在create按钮旁边的文本框中，输入我们即将要创建的数字货币的初始化参数，如：

"200000000","ColorBayToken","CBT"

以上参数都可以按照自己的想法随意填写，但注意发行总量至少大于0，否则发布没有意义。
接下来点击create按钮，如图：

弹出MateMask交易对话框，点击SUBMIT，如图：

此时创建合约的操作进入交易池，等待被打包到区块，稍等一会我们的合约就创建完成了。

我们通过MetaMask去查看一下合约的创建详情，如图：

点击SENT栏中的交易，跳转到测试网络，如：
https://ropsten.etherscan.io/tx/0x539a955ef95ace073f6a37514fc3d3f29e3a266c00760cf2c9af38225d5456f4
交易详情解释如下：

如上图，在交易中，我们可以看到simon的合约管理员地址，点击我们的合约地址，
0x77d85a6184f9a71f293704fe57b5e7142db95ef6

6、添加Token到我们的钱包地址

image.png

至此，我们的数字货币就发行好了，开始走上“一币一嫩模”的巅峰人生，过着不用上班全球闲游的生活O(∩_∩)O~ ......

三、分配激励

以下纯属假设，笔者仅凭看过的白皮书与结合智能合约中的方法进行猜测，没有经历具体项目的激励分配过程，不然也不在这写文章了（咱发柴了还在这写个毛线），欢迎指正。

1、假设我们发行的ColorBayToken的激励方案如下：

发行总量为 200,000,000 个token
激励占比40%，即80,000,000个token
私募占比20%，即40,000,000个token
团队及基金会占比25%，即50,000,000个token
社区培养及推广占比15%，即30,000,000个token

2、测试用例及账号
我们以合约管理员Simon给团队及基金会（以下简称Team）分配50,000,000个token可用额度、Team要给团队成员Ouyang转账10000个token为例。
Simon的钱包地址为：0x2D80ed00A372AF341887F473eD6241f1973C5D59
Team的钱包地址为：0x1251b21727401E8d386C5794a2d0375E400b2272
Ouyang的钱包地址为：0x286870be6B845964b8EeeACA6f42942812269978

3、Simon给Team批量分配50000000000个token额度
即调用合约方法approve("Team的钱包地址", "token额度")。
具体操作：我们先在MetaMask中切换到合约管理员Simon钱包地址，回到Remix界面中，在右边的调试区，将"0x1251b21727401E8d386C5794a2d0375E400b2272", "50000000000000000000000000"（注意：数字后面要多加18位0，换算成以太坊的基本单位wei）放入approve按钮旁边的文本框，点击approve按钮，如图：

点击提交交易。稍后我们可以去MetaMask中查看交易详情，点击最新的一笔交易，跳转到如：https://ropsten.etherscan.io/tx/0xb88cb8dfccb48a08235079ad8f4d722e414a8fc0e98b7ba30e183b66eb43f0f9
稍等一会我们的交易就完成了。
我们来验证一下，在allowance按钮旁边输入"0x2D80ed00A372AF341887F473eD6241f1973C5D59","0x1251b21727401E8d386C5794a2d0375E400b2272"，点击allowance按钮，可以看到可用token额度为50000000000000000000000000。

值得注意的是，我们这里只是分配给Team可用额度，并不是立即到账，只有当Team要使用的时候通过下面的操作才能到账。如果没有明白，请接着往下看。

4、Team给团队成员Ouyang转账10000个token
当前Team钱包地址的token数是0，但Team在Simon那里有token使用额度（因为上一步Simon已经授权了Team额度为50000000000000000000000000），所以Team可以授权让Ouyang去Simon钱包地址里拿，即调用合约方法transferFrom("Simon的钱包地址", "Ouyang的钱包地址", "token额度")。
具体操作：在MetaMask中切换到Team钱包地址（表示Team要出面授权了），回到Remix界面中，在右边的调试区，将"0x2D80ed00A372AF341887F473eD6241f1973C5D59","0x286870be6B845964b8EeeACA6f42942812269978","10000000000000000000000"放入transferFrom按钮旁边的文本框，点击transferFrom按钮，弹出MetaMask交易窗口，如图：

点击提交交易，稍后我们就可以看到交易生效。
我们来验证一下，Ouyang是否已经拿到了Team给的token，在MetaMask中切换到Ouyang钱包地址，我们可以看到TOKENS一栏显示了10000个CBT。

我们再来验证一下Team的剩余额度，在allowance按钮旁边输入"0x2D80ed00A372AF341887F473eD6241f1973C5D59","0x1251b21727401E8d386C5794a2d0375E400b2272"，点击allowance按钮，可以看到可用token额度为49990000000000000000000000，少了一些。

5、通过MyEtherWallet转账
第2、3、4步，我们是通过Remix+MetaMask，且是一些批量操作，对普通投资人或小韭菜操作不够友好，下面我们通过在线钱包网站MyEtherWallet.com+MetaMask来演示一下转账。
假设Ouyang要卖出2000个CBT给张三（zhangsan钱包地址：0x3B723028e3585dc936a0F6CC52534322d2d65D73），付款方式：私下交易C2C。
如下图目前zhangsan钱包余额为 0 CBT。

具体操作：
打开MyEtherWallet.com网站，点击“发送以太币/发送代币”链接，选择Network Ropsten(infura.io)，选择MetaMask/Mist，点击Connect to MetaMask按钮。

在新展示的页面右下角，添加我们的Token：

添加完后的效果：

如下图，填写zhangsan的钱包地址，填写转账数额，选择CBT，点击生成交易，

弹出确认交易界面，点击“是的，我确定！发送交易”按钮。

弹出MetaMask交易对话框，点击“SUBMIT”提交交易

稍后我们的交易就成功了，看看，张三是不是已经到账了？

本文原创，转载请注明出处：https://www.jianshu.com/p/c436e90d4354
欢迎加微信与我一起学习交流！

微信交流

【以太坊开发】手把手教你发布众筹智能合约进行ICO
前言上一篇：【以太坊开发】手把手教你发个数字货币及怎样分配激励token CBT我们已经发行好了，接下来该ICO...
【以太坊开发】手把手教你发个数字货币及怎样分配激励
笔者这些天从以太坊官网etherscan.io扒了一些token的源代码，如ABT、DRGN、BNB、EOS等，发...
以太坊Solidity开发入门(基础篇)
分享一个很有趣的以太坊开发教程。从零开始手把手教你以太坊开发。第1章: 课程概述第一课你将创造一个"僵尸工厂"...
新的机遇！俄罗斯国家开发银行发行自己的数字货币VEB了！
最近，俄罗斯国家开发银行最近和数字货币以太坊的开发团队合作共同推出了全新的数字货币EVB。这是俄罗斯政府在区...
solidity 0.5.7简明教程
以太坊不仅是一种加密数字货币，它更是功能完备的智能合约平台，solidity就是用来开发以太坊上的智能合约的原生开...
如何购买以太坊
以太坊ETH是一种区块链技术，而以太币是以太坊的原生代币。随着以太坊价格的暴涨以及数字货币被人们所承认，以太坊交易...
如何购买以太坊
如何购买以太坊以太坊ETH是一种区块链技术，而以太币是以太坊的原生代币。随着以太坊价格的暴涨以及数字货币被人们所...
切记盲目参与项目，加密数字货币的四大特点
投资数字货币，必须了解数字货币的特性。什么是数字货币数字货币，也就是我们常说的“比特币”、“以太坊”，这是一种...
V神：震惊世界的天才少年！
如果是比特币是数字货币开山鼻祖的话，以太坊就是数字货币的造人女蜗。截止目前依然有90%的区块链应用项目通过以太坊搭...
币圈知识:交易所基础交易名词及术语解释
1、什么是数字货币？数字货币指不依托任何实物，使用密码算法的数字货币，比如比特币（BTC）、以太坊（ETH）等，...